How to translate Arduino demos into BrickPixel demos

When looking for examples of lighting control using the Arduino, you will usually find code that uses the on-board LED as the light.  The control logic in the code is what's needed, but how can that be translated to working with the BrickPixel Arduino shield?

The following shows what, at a minimum, needs to be added to Arduino demo examples to make them work with BrickPixel.

Here is an Arduino demo that comes with the Arduino IDE.

/*
  Blink without Delay

  Turns on and off a light emitting diode (LED) connected to a digital pin,
  without using the delay() function. This means that other code can run at the
  same time without being interrupted by the LED code.

  The circuit:
  - Use the onboard LED.
  - Note: Most Arduinos have an on-board LED you can control. On the UNO, MEGA
    and ZERO it is attached to digital pin 13, on MKR1000 on pin 6. LED_BUILTIN
    is set to the correct LED pin independent of which board is used.
    If you want to know what pin the on-board LED is connected to on your
    Arduino model, check the Technical Specs of your board at:
    https://www.arduino.cc/en/Main/Products

  created 2005
  by David A. Mellis
  modified 8 Feb 2010
  by Paul Stoffregen
  modified 11 Nov 2013
  by Scott Fitzgerald
  modified 9 Jan 2017
  by Arturo Guadalupi

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay
*/

// constants won't change. Used here to set a pin number:
const int ledPin = LED_BUILTIN;// the number of the LED pin

// Variables will change:
int ledState = LOW;             // ledState used to set the LED

// Generally, you should use "unsigned long" for variables that hold time
// The value will quickly become too large for an int to store
unsigned long previousMillis = 0;        // will store last time LED was updated

// constants won't change:
const long interval = 1000;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the difference
  // between the current time and last time you blinked the LED is bigger than
  // the interval at which you want to blink the LED.
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;

    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW) {
      ledState = HIGH;
    } else {
      ledState = LOW;
    }

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
}

This is an altered version that adds what is needed by the BrickPixel system.  This example keeps everything in the original program, so the Arduino on-board LED will work as before,  with the addition of the first pixel (or LED) in the BrickPixel light string replicating what the on-board LED is doing.

/* Blink without Delay with added BrickPixel commands
*/

// library for controlling the BrickPixel hardware (REQUIRED)
#include <Adafruit_NeoPixel.h>

// constants won't change. Used here to set a pin number:
const int ledPin = LED_BUILTIN;// the number of the LED pin

// The BrickPixel equivalent of ledPin
Adafruit_NeoPixel pixels(1, 7, NEO_RGB + NEO_KHZ800);

// Variables will change:
int ledState = LOW;             // ledState used to set the LED

// Generally, you should use "unsigned long" for variables that hold time
// The value will quickly become too large for an int to store
unsigned long previousMillis = 0;        // will store last time LED was updated

// constants won't change:
const long interval = 1000;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);

 // Initialize the NeoPixel object (this is REQUIRED)
 pixels.begin();

 // Clear out any prior BrickPixel settings
 pixels.clear();
}

void loop() {
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the difference
  // between the current time and last time you blinked the LED is bigger than
  // the interval at which you want to blink the LED.
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;

    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW) {
      ledState = HIGH;
      // the equivalent of ledState HIGH
      pixels.setPixelColor( 0, pixels.Color(255, 0, 0) );
    } else {
      ledState = LOW;
      // the equivalent of ledState LOW
      pixels.setPixelColor( 0, pixels.Color(0, 0, 0) );
    }

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);

    // set the pixel with the pixelState
    pixels.show();
  }
}

The changes [listed in bold above] are:

  1.  Adding the Adafruit library that allow control of the BrickPixel system
  2.  Creating an equivalent BrickPixel LED address to send the control commands to
  3.  Setting up the BrickPixel to be ready for control commands
  4.  Setting the BrickPixel LED to maximum brightness (HIGH state) or minimum brightness (LOW state)
  5.  Sending the updated LED state to the BrickPixel

Sometimes you might see the reference to the LED output address on the Arduino as  pinMode(LED_BUILTIN, OUTPUT); or pinMode(9, OUTPUT); instead of the combination used the Arduino demo program above.

// constants won't change. Used here to set a pin number:
const int ledPin = LED_BUILTIN;// the number of the LED pin
.
.
.
// set the digital pin as output:
pinMode(ledPin, OUTPUT);

This won't change what is added to have the BrickPixel work.

If you have any problems, questions, comments or suggestions, post'em here or PM me.

-wrtyler-

Reply Oldest first
  • Oldest first
  • Newest first
  • Active threads
  • Popular
Like Follow
  • 3 wk agoLast active
  • 3Views
  • 1 Following